
Лабораторная работа 16
Слоты задержки Комдив-МК и влияние уровней оптимизации GCC на генерацию ассемблерного кода

Полузеров А.Ю., Мощевикин А.П., ПетрГУ

Цель: изучить особенности конвейерного выполнения команд в архитектуре микроконтроллера К5500ВК018 (Комдив-МК). Познакомиться с понятиями «слот задержки ветвления» и «слот задержки загрузки». Исследовать, как различные уровни оптимизации компилятора GCC влияют на генерацию ассемблерного кода, заполнение слотов задержки и итоговую производительность.

Конвейер и конфликты (Hazards)

В микроконтроллер К5500ВК018 встроены две ключевые технологии, которые используются в современных процессорах для ускорения их работы за счет параллельного выполнения команд: конвейер и суперскалярность. Конвейер – это последовательное совмещение разных этапов разных инструкций, а суперскалярность – это параллельное выполнение нескольких инструкций (потоков) одновременно благодаря наличию дополнительных аппаратных вычислительных блоков. Комдив-МК поддерживает три потока: F-, M- и FP-потоки.

Человек (или ИИ) разрабатывает программу. С помощью компилятора переводит ее в машинный код. Код состоит из последовательно выполняемых инструкций. В архитектуре КОМДИВ (как и в архитектуре MIPS) все инструкции занимают одинаковое количество байтов – 4 байта (32 бита). Когда очередная инструкция (например, addiu v0,v0,1) попадает в процессор, он ее выполняет. Выполнение инструкции проходит за несколько тактов.
Без конвейера процессор ждал бы полной обработки одной команды и только потом брал следующую. С конвейером процессор выполняет шаги одновременно (псевдопараллельно): пока первая команда исполняется, вторая уже декодируется, а третья считывается из памяти. Это позволяет существенно поднять общую скорость работы.
Стандартно, выделяют 5 стадий конвейера:
1. Fetch – выборка (чтение) инструкции из памяти.
2. Decode – декодирование (распознавание, что нужно сделать).
3. Execute – исполнение команды.
4. Memory – доступ к памяти (если нужно сохранить или прочитать данные).
5. Writeback – запись готового результата обратно в регистры.
В архитектуре КОМДИВ используется 7-тактовый конвейер, см. рисунок 1 [1, раздел 1].

Рисунок 1 – Стадии конвейера в архитектуре КОМДИВ [1].

Исполнение инструкции «размазано» на 7 тактов процессора (примечание: частота тактирования К5500ВК018 установлена в значение 300 МГц, длительность тактового сигнала равна 3.3 нс).
Как показано на рисунке 1, в промежуток с 1-го по 3-ий такт происходит выборка инструкции. Ячейка ID (последняя в общем потоке General) соответствует классической второй стадии декодирования инструкции. На четвертом такте происходит распараллеливание: передача исполнения в один из трех потоков.
1)	F-поток – целочисленная арифметика (ALU1). В нем выполняются инструкции целочисленной арифметики, инструкции ветвления и инструкции записи/чтения внутренних регистров HI, LO.
2)	M-поток – обращение к памяти (ALU2). В нем выполняются инструкции обращения к памяти (инструкции Load/Store), инструкции перемещения данных (Move), в том числе и в сопроцессор, а также основные инструкции целочисленной арифметики.
3)	FP-поток – вещественная арифметика (FPU). В нем выполняются арифметические инструкции и инструкции ветвления FPU (вещественного сопроцессора CP1).

Наличие параллельных потоков и взаимозависимость результатов в их расчетах может порождать аппаратные конфликты (Hazards). 
Примером таких конфликтов может являться ситуация, когда выполнение одной инструкции зависит от результата работы другой инструкции, которая еще не успела завершить свое выполнение на конвейере.
Чтобы их избежать, в архитектуре КОМДИВ (MIPS) предусмотрены два вида слотов задержки.
1. Слот задержки команды ветвления (Branch Delay Slot). 
В момент, когда команда перехода (beq, bne, jal и др.) достигает стадии выполнения, следующая за ней команда уже находится в конвейере. Т.е., по-любому, будет выполнена независимо от того, произойдет переход или нет. Чтобы решить эту проблему «непреднамеренного» исполнения компилятор может самостоятельно добавить в код инструкцию nop после инструкции перехода.
2. Слот задержки команды загрузки (Load Delay Slot).
Команда загрузки из памяти (lw, ld) – это фактически две операции: вычисление адреса и чтение данных. Результат загрузки не может быть сразу использован следующей командой. Необходимо подождать. Здесь два пути. Либо компилятор вставляет команду nop после инструкции загрузки из памяти, либо аппаратная часть процессора при исполнении кода автоматически остановит конвейер (создаст аппаратный «пузырь» или stall) на 1 такт.
Следует отметить, что компилятор может использовать слот задержки более умно. Он может перемешать порядок следования инструкций, задуманный программистом, и вставить в него какое-то полезное действие, а не оператор nop.

Уровни оптимизации компилятора GCC и поведение ППП МК

Компилятор gcc использует планирование инструкций (Instruction Scheduling), чтобы менять порядок команд местами и заполнять слоты задержки полезными инструкциями.
В отличие от стандартной поставки GCC, где по умолчанию действует -O0, в сборочной системе ППП МК [4] (в Makefile) по умолчанию уже включена оптимизация (обычно -O2), так как это стандартная практика для встраиваемых систем. Чтобы изучить неоптимизированный код или, наоборот, применить агрессивные оптимизации к отдельным функциям, не меняя глобальные настройки Makefile, используется директива препроцессора #pragma GCC optimize.
Основные уровни оптимизации:
· -O0 – оптимизация отключена. Компилятор генерирует код «как написано в Си». Локальные переменные хранятся в стеке, слоты задержки заполняются программными nop.
· -O1 – базовая оптимизация. Компилятор старается держать переменные в регистрах (уменьшая обращения к стеку) и удаляет недостижимый код.
· -O2 – стандартная оптимизация для встраиваемых систем. Включается агрессивное планирование инструкций. Компилятор ищет независимые инструкции для заполнения слотов задержки загрузки и ветвления.
· -O3 – включает все из -O2, а также применяет раскрутку циклов (loop unrolling) и встраивание функций (inlining). Тело цикла дублируется несколько раз, чтобы уменьшить количество команд ветвления и максимально загрузить конвейер. Этот уровень оптимизации дает самый быстро исполняемый код, но приводит к увеличению размера файла прошивки.
· -Os – оптимизация по размеру кода. Отключает раскрутку циклов, чтобы уменьшить объем занимаемой Flash-памяти.

Примеры анализа ассемблерного кода

Рассмотрим, как компилятор обрабатывает простой цикл вычисления суммы элементов массива data из 16 чисел. Для чистоты эксперимента функция завершается записью результата в data[0], что предотвращает удаление цикла компилятором как «бесполезного». 

#pragma GCC optimize ("O0") // Уровень оптимизации меняется для каждого варианта
#define BLOCK_SIZE 16 
int data[BLOCK_SIZE];

void process_block(int *data) {
    int i,sum = 0;
    for (i = 0; i < BLOCK_SIZE; i++) {
        sum += data[i];
    }
    data[0] = sum; // Операция над результатом необходима, чтобы компилятор не вырезал цикл
}
. . .
int main(void) {
    . . .
    for (i = 0; i < BLOCK_SIZE; i++) {data[i] = i}; // инициализация массива data
    process_block(data); // расчет суммы элементов; результат записывается в data[0]
    . . .


Вариант 1: Без оптимизации (-O0)
  addiu sp,sp,-16      # Пролог: выделение места в стеке
  sw    s8,12(sp)      # Сохранение старого указателя кадра
  move  s8,sp          # Установка нового указателя кадра (s8)
  sw    a0,16(s8)      # Сохранение аргумента data в стеке (указатель на массив data)
  sw    zero,4(s8)     # sum = 0 (локальная переменная в стеке по смещению 4)
  sw    zero,0(s8)     # i = 0 (локальная переменная в стеке по смещению 0)
  b     80000d5c       # Безусловный переход к проверке условия цикла [loop_check]
  nop                  # [СЛОТ ВЕТВЛЕНИЯ] Программный NOP

loop_body:             # Метка начала тела цикла (адрес 80000d30)
  lw    v0,0(s8)       # Загрузка i из стека
  sll   v0,v0,0x2      # i * 4 (вычисление байтового смещения элемента в массиве data)
  lw    v1,16(s8)      # Загрузка указателя data из стека
  addu  v0,v1,v0       # Формирование адреса &data[i]=&data[0]+ i*4
  lw    v0,0(v0)       # Загрузка значения data[i]
  lw    v1,4(s8)       # Загрузка sum из стека
  addu  v0,v1,v0       # sum = sum + data[i]
  sw    v0,4(s8)       # Сохранение обновленного sum в стек
  lw    v0,0(s8)       # Загрузка i из стека для инкремента
  addiu v0,v0,1        # i = i + 1
  sw    v0,0(s8)       # Сохранение обновленного i в стек

loop_check:            # Метка проверки условия (адрес 80000d5c)		  
  lw    v0,0(s8)       # Загрузка i для проверки условия
  slti  v0,v0,16       # Сравнение: v0 = (i < 16)
  bnez  v0,80000d30    # Если i < 16, переход на начало тела цикла [loop_body]
  nop                  # [СЛОТ ВЕТВЛЕНИЯ] Программный NOP
# ... далее следует эпилог: загрузка sum и data из стека, запись data[0] = sum, 
# восстановление регистра s8, указателя стека и возврат jr ra с nop в слоте задержки.

Компилятор генерирует код «как написано». Поскольку все переменные (i, sum, data[]) объявлены локально или переданы как аргументы, при отключенной оптимизации компилятор хранит их в стеке. Доступ к ним осуществляется через указатель кадра s8. Цикл начинается с безусловного перехода b к проверке условия (адрес 80000d5c), чтобы корректно обработать случай, когда цикл не должен выполняться ни разу. Слот задержки этого перехода заполнен инструкцией nop.
В теле цикла на каждой итерации происходят: загрузка i, вычисление адреса элемента, загрузка data[i], загрузка sum, сложение и запись sum обратно в стек. Затем i загружается, инкрементируется и снова сохраняется в стек. Проверка условия завершает итерацию, и переход bnez возвращает управление на адрес 80000d30. Слот задержки этого перехода также заполнен инструкцией nop.
Тело цикла (от метки перехода до bnez включительно) содержит 14 инструкций. Для 16 итераций это 224 инструкции только на выполнение цикла, не считая пролога и эпилога. Все слоты задержки заполнены «пустыми» инструкциями nop, конвейер процессора простаивает, производительность минимальна. 

Вариант 2: Базовая оптимизация (-O1)
  move  v0,a0          # v0 = data (текущий указатель)
  addiu a2,a0,64       # a2 = data + 64 (указатель на конец массива)
  move  v1,zero        # v1 = 0 (это наш sum)

loop_body:             # Метка начала тела цикла (адрес 80000e10)
  lw    a1,0(v0)       # Загрузка текущего элемента data[i] в a1
  addiu v0,v0,4        # [СЛОТ ЗАГРУЗКИ] Сдвиг указателя на 4 байта вперед
  bne   v0,a2,80000e10 # Сравнение указателей: если не конец, прыжок на [loop_body]
  addu  v1,v1,a1       # [СЛОТ ВЕТВЛЕНИЯ] sum += data[i]
  jr    ra             # Возврат из функции
  sw    v1,0(a0)       # [СЛОТ ВЕТВЛЕНИЯ jr] data[0] = sum

Компилятор полностью устраняет обращения к стеку для переменных i и sum, размещая их в регистрах (v1 для суммы). Индексация массива заменяется на арифметику указателей: регистр v0 инициализируется как начало массива, а a2 как его конец (a0 + 16 * 4 байта).
В теле цикла инструкция lw загружает элемент. Следом идет addiu, которая сдвигает указатель. Это ключевой момент: инструкция addiu не зависит от результата lw, поэтому она идеально заполняет слот задержки загрузки (Load Delay Slot). Далее следует проверка условия bne, а в слоте задержки ветвления выполняется полезное действие – сложение addu v1, v1, a1. Наконец, при выходе из функции инструкция возврата jr ra использует свой слот задержки для финальной записи результата в data[0].

Тело цикла сократилось до 4 инструкций. Для 16 итераций это 64 инструкции (против 224 в -O0). Выигрыш в производительности составляет более 3.5 раз только за счет сокращения динамического числа команд. Объем кода функции уменьшился с ~32 до 9 инструкций. Программные nop и аппаратные stall полностью устранены за счет грамотного планирования. 

Вариант 3: Стандартная оптимизация (-O2)

Для данного простого цикла ассемблерный листинг на уровне -O2 полностью идентичен варианту -O1. Планировщик инструкций на уровне -O1 уже нашел оптимальное расположение команд для заполнения слотов задержки. Дополнительное агрессивное планирование на -O2 не дало выигрыша для этого конкретного паттерна, поэтому цикл остался в том же виде.

Вариант 4: Агрессивная оптимизация (-O3)
lw    v0,0(a0)       # Загрузка data[0] в v0
lw    a2,4(a0)       # Загрузка data[1] в a2
lw    a1,8(a0)       # Загрузка data[2] в a1
lw    v1,12(a0)      # Загрузка data[3] в v1
addu  v0,v0,a2       # sum = data[0] + data[1]
addu  v0,v0,a1       # sum += data[2]
lw    a2,16(a0)      # Загрузка data[4] в a2
lw    a1,20(a0)      # Загрузка data[5] в a1
addu  v0,v0,v1       # sum += data[3]
addu  v0,v0,a2       # sum += data[4]
# ... (аналогичные блоки для элементов 6-7, 8-11, 12-15)
addu  v0,v1,v0       # Финальное сложение: sum += data[15] (v1 хранит последний элемент)
jr    ra             # Возврат из функции
sw    v0,0(a0)       # [СЛОТ ВЕТВЛЕНИЯ jr] data[0] = sum

На уровне -O3 компилятор применил полную раскрутку цикла (loop unrolling). Тело цикла было «раскатано» в прямую линию инструкций, и инструкция ветвления (bne) исчезла из кода.
Обратите пристальное внимание на порядок сложения в первом блоке. После загрузки data[0]..data[3] в регистры v0, a2, a1, v1 компилятор сначала складывает data[0]+data[1] и +data[2]. А затем, после загрузки следующих элементов, добавляет data[3] (addu v0, v0, v1).
Это не ошибка и не потеря данных. Это демонстрация работы планировщика инструкций:
· Слот задержки инструкции lw v1, 12(a0) (загрузка data[3]) успешно заполнен независимой инструкцией addu v0, v0, a2.
· Далее идут загрузки data[4] и data[5].
· Инструкция сложения data[3] (addu v0, v0, v1) размещена ровно в слоте задержки загрузки инструкции lw a1, 20(a0) (загрузка data[5]). 
· Почему это безопасно? Потому что к моменту выполнения сложения data[3] значение регистра v1 уже давно готово, а сама операция сложения не зависит от регистра a1 (в который только что загрузился data[5]). 
Таким образом, компилятор намеренно «отложил» использование data[3], чтобы найти для этой арифметической операции идеальное место спустя несколько тактов, закрыв тем самым слот задержки от другой инструкции загрузки и максимально уплотнив конвейер без единого аппаратного stall.

В данном случае для обработки 16 элементов выполняется ровно 16 инструкций lw и 15 инструкций addu. Итого 31 инструкция внутри основного блока. Это примерно в 2 раза меньше команд, чем в варианте -O1 (64 инструкции), что дает существенный выигрыш в скорости. Скомпилированная функция содержит 33 инструкции, т.е. в 3.6 раза больше, чем код в варианте -O1 (9 инструкций).

На самом деле, агрессивный флаг оптимизации -O3 нужно использовать с осторожностью для микроконтроллеров по трем главным причинам:
1. Раздувание кода: -O3 встраивает функции (inlining) и разворачивает циклы ради скорости. Это резко увеличивает размер прошивки, и она может не поместиться во Flash-память микроконтроллера.
2. Возможные сбои в работе с железом: компилятор переупорядочивает инструкции и удаляет «лишний» код. 
А. Уничтожение циклов ожидания (Busy-wait loops)
Если для инициализации внешнего датчика или дисплея нужно подождать несколько миллисекунд, программист часто пишет пустой цикл: for (int i=0; i<5000; i++);. При оптимизации -O3 компилятор видит, что переменная i нигде дальше не используется, а сам цикл не производит никаких полезных вычислений. Он полностью удаляет этот цикл при компиляции. В итоге в бинарном коде задержка исчезает, сигналы подаются слишком быстро, и периферия просто не успевает проснуться.
Б. Игнорирование изменений в регистрах (проблема volatile)
Микроконтроллер общается с внешним миром через аппаратные регистры, которые привязаны к конкретным адресам памяти. Если микроконтроллер ждет, пока аппаратура поднимет флаг готовности (например, while (UART->STATUS == 0);), компилятор на уровне -O3 может решить: «Так, в цикле значение по этому адресу никто не меняет, значит, можно прочитать его один раз в регистр процессора и крутить бесконечный цикл на основе этого сохраненного значения». Программа зависает в вечном цикле, даже если физически в памяти флаг уже изменился. Без явного указания volatile компилятор сгенерирует неверный бинарный код.
В. Удаление «лишней» записи (Write-only оптимизация)
Компилятор может заметить, что программист дважды подряд записывает данные в одну и ту же переменную (или адрес памяти) без ее промежуточного чтения. На уровне -O3 он объединит это или выбросит первую запись как избыточную. Но для железа это критично: первая запись могла быть командой «включить питание», а вторая – «передать данные». В результате первая команда до физического регистра просто не дойдет.
Г. Агрессивное переупорядочивание инструкций
Ради эффективной загрузки конвейера процессора -O3 меняет строки кода местами, если не видит между ними прямой логической зависимости. В несложных программах это незаметно, но в embedded-системах строгий порядок важен. Если компилятор поменяет местами настройку частоты тактирования и подачу питания на модуль, периферия выдаст аппаратный сбой (HardFault) или начнет слать в шину случайный мусор.
3. Невозможная отладка: из-за жесткой перестройки ассемблерного кода переменные «исчезают», а точки останова (breakpoints) прыгают по строкам, что превращает дебаг через JTAG/SWD в хаос.

Для микроконтроллеров безопаснее использовать -Os (оптимизация по размеру) или -O2.
Кроме этого, для уменьшения эффекта переупорядочивания инструкций при использовании оптимизации рекомендуется использовать барьеры памяти.

Задание для самостоятельной работы

Примечание 1: Для всех замеров используется функция get_cpu_cycles(), читающая регистр CP0 Count. 
Примечание 2: Код ниже специально написан неоптимальным способом, чтобы продемонстрировать разницу в результатах компиляции для разных уровней оптимизации.

1. Напишите программу на языке Си, содержащую функцию example, которая работает с глобальными массивами: 

#define BLOCK_SIZE 16

#pragma GCC optimize ("O0")
void example(int *a, int *b, int *c);
void example(int *a, int *b, int *c){
    int i, sum = 0;
    int val_a, val_c;
    for (i = 0; i < BLOCK_SIZE; i++) {
        val_a = a[i];
        val_c = c[i];
        sum+=val_a;
        b[i] = sum + val_c;
    }
}

Создайте глобальные массивы a, b, c из BLOCK_SIZE элементов (BLOCK_SIZE = 16) и заполните содержимое массивов a и c, например, с помощью предложенного цикла в функции main, перед вызовом функции example:
for(i = 0; i < BLOCK_SIZE; i++){
    a[i] = i;
    c[i] = -i;
}
Передача массивов в функцию происходит с помощью указателей. 
Примечание 1: Если массивы останутся неинициализированными, это может исказить работу конвейера и подсистемы памяти: цель лабораторной работы может быть не достигнута.
Примечание 2: Обратите внимание, что константа BLOCK_SIZE объявлена через директиву препроцессора #define. Это означает, что на этапе компиляции компилятор уже знает точный размер массива и количество итераций цикла. Благодаря этому, на агрессивных уровнях оптимизации (например, -O3), компилятор может безопасно применить полную раскрутку цикла (loop unrolling), превратив его в линейный код без инструкций ветвления, так как ему не нужно вычислять условие выхода «на лету». 
Скомпилируйте проект четыре раза, принудительно меняя уровень оптимизации для этой функции с помощью директив в начале файла main.c:
· Первый раз: #pragma GCC optimize ("O0")
· Второй раз: #pragma GCC optimize ("O1")
· Третий раз: #pragma GCC optimize ("O2")
· Четвертый раз: #pragma GCC optimize ("O3")
Откройте сгенерированный файл .dis для каждого из трех случаев. Найдите дизассемблерный листинг функции example. Для каждого уровня оптимизации ответьте на вопросы и занесите данные в Таблицу 1:
· Сколько инструкций приходится на одну итерацию цикла (или на одну «раскрученную» итерацию)?
· Присутствуют ли в коде инструкции nop? Если да, то в каких слотах задержки они стоят?
· Как компилятор заполняет слот задержки ветвления?
· Применена ли раскрутка цикла?

Таблица 1.
	Уровень оптимизации
	Кол-во инструкций на итерацию
	Наличие nop или аппаратных stall и их расположение
	Заполнение слота ветвления
	Раскрутка цикла (Loop unrolling)

	-O0
	
	
	
	

	-O1
	
	
	
	

	-O2
	
	
	
	

	-O3
	
	
	
	



2. В функции main организуйте цикл, который вызывает функцию example из задания 1 большое количество раз (например, ITERATIONS = 1000), чтобы код по времени выполнялся долго. 
· С помощью функции get_cpu_cycles() замерьте общее количество тактов, затраченных на выполнение всех ITERATIONS вызовов для каждого из четырех уровней оптимизации (-O0, -O1, -O2, -O3).
· [bookmark: _GoBack]Рассчитайте среднее время выполнения одного прохода по массиву (в тактах) для каждого уровня.
· Занесите результаты в Таблицу 2 и рассчитайте во сколько раз оптимизированный код быстрее неоптимизированного кода (-O0). 
Таблица 2.
	Уровень оптимизации
	Количество тактов за 1000 итераций
	Тактов на 1 проход 
	Коэффициент ускорения

	-O0
	
	
	1

	-O1
	
	
	

	-O2
	
	
	

	-O3
	
	
	



Разработчики платы БАГЕТ-ПЛК1-01 [2] рекомендуют использовать среду разработки и структуру проекта, описанные в [3] и [4, раздел 3]. 
Задания к лабораторной работе подразумевают, что работа выполняется в ОС Windows с предустановленной виртуальной машиной WSL2 с Debian [3] и ППП МК [4-5]. Проекты на языке Cи следует создавать в папке ./psp_mc/apps/ .
Для формирования импульса можно использовать функцию delay_us(), для замера времени работы –__micros(), для вывода результата – __print_console(), для форматирования строки вывода – itoa() и intToHex().

