
Лабораторная работа 11
Аппаратный замер времени выполнения и анализ машинного кода в архитектуре КОМДИВ64

Полузеров А.Ю., Мощевикин А.П., ПетрГУ

[bookmark: _GoBack]Цель: Исследование архитектурных особенностей суперскалярного процессорного ядра КОМДИВ64 (К5500ВК018), приобретение практических навыков анализа дизассемблированного машинного кода и аппаратной оценки производительности программных фрагментов с учетом конвейерной обработки, слотов задержки и оптимизаций компилятора.

Архитектурные особенности ядра

Микросхема К5500ВК018 – это система на кристалле, которая включает процессорное ядро с архитектурой КОМДИВ64 (совместимой с MIPS64) для обработки 32- и 64-разрядных чисел с фиксированной запятой и арифметический сопроцессор для обработки чисел с плавающей запятой одинарной и двойной точности.
Ядро Комдив-МК реализует 7-стадийный конвейер и обладает свойствами суперскалярности. Это означает, что процессор может выдавать на выполнение до двух инструкций за один такт, если они принадлежат разным функциональным потокам:
· F-поток (ALU1): целочисленная арифметика, логика, сдвиги, ветвления.
· M-поток (ALU2): обращения к памяти, перемещение данных, целочисленная арифметика.
· FP-поток (FPU): операции с плавающей запятой.

В ходе компиляции и сборки проекта формируется файл – образ прошивки, который должен быть помещен в ПЗУ. Он представляет собой скомпилированный бинарный код, содержащий машинные инструкции, а также константные данные (таблицы, строки, калибровки), необходимые для запуска и работы устройства.
Файл прошивки чаще всего имеет расширение .bin, .hex или .elf.

Полный список инструкций микроконтроллера, их принадлежность к потокам и длительность их выполнения в тактах приведен в [1, раздел 4].
В качестве примера в таблице 1 приведены несколько часто используемых инструкций. Поле задержка соответствует длительности выполнения инструкции в тактах процессора.

Таблица 1. Описание некоторых инструкций микроконтроллера.

	Команда
	Описание
	Поток
	Задержка

	MULT
	Целочисленное умножение с учетом знака (32 бита)
	F
	2

	BNE
	Переход, если значения двух регистров (операндов) не равны
	F
	1

	NOP
	Нет операции (No Operation)
	F
	1

	SW
	Сохранение 32-битного слова из регистра общего назначения в оперативную память (Store Word)
	M
	2

	MUL.fmt
	Умножение (вещественная арифметика); суффикс после fmt указывает формат данных: S (одинарная точность), D (двойная)…
	FP
	4

	ROUND.W.fmt
	Преобразование вещественного числа в 32-битное целое со знаком с округлением до ближайшего целого
	FP
	4

	MFC0
	Чтение слова из регистра управляющего сопроцессора CP0
	M
	1



Анализ дизассемблированного кода

После сборки проекта в среде WSL/Debian (ППП МК) в папке проекта помимо файлов с расширением .bin и .elf генерируется файл с расширением .dis. Он содержит дизассемблированный листинг. Открыть его можно с помощью Visual Studio Code. Найти фрагмент нужной функции можно с помощью поиска (сочетание клавиш Ctrl+F).
Каждая строка в .dis файле соответствует одной 32-битной машинной инструкции. Формат строки приведен ниже.
Адрес в памяти : Машинный код   Мнемоника   Операнды
Рассмотрим пример – операция загрузки данных из памяти.
80001094: 8fc20024 	lw	v0,36(s8)
1. Адрес в памяти (80001094) – шестнадцатеричный адрес в оперативной памяти (или ПЗУ), где физически расположена данная инструкция.
2. Машинный код / Опкод (8fc20024) – значение кода инструкции в шестнадцатеричном формате. 8 символов = 32 бита.
3. Мнемоника (lw) – краткое текстовое название команды (от англ. Load Word — загрузить слово).
4. Операнды (v0, 36(s8)) – объекты, над которыми выполняется команда. 
В архитектуре MIPS действует строгое правило: сначала указывается куда кладем результат, а потом откуда берем данные.
v0 – имя регистра процессора.
36(s8) – адрес в оперативной памяти. Считается по формуле: 
Адрес в памяти = Значение в регистре s8 + Смещение 36.

Слоты задержки (Delay Slots)
В архитектуре MIPS команда ветвления и команда загрузки из памяти имеют слот задержки. Компилятор либо вставляет в слот задержки инструкцию NOP (no operation), либо использует этот слот «с умом». Например, вставляет в него команду, следующую сразу за командой перехода.
Таким образом, инструкция, стоящая в памяти сразу после команды ветвления, может быть выполнена процессором до того, как переход фактически произойдет! Это необходимо учитывать при анализе циклов.

Аппаратный замер времени (регистр Count)

Для оценки времени выполнения отдельных инструкций использование таймера TS недостаточно точно (шаг 10 нс). В архитектуре Комдив-МК предусмотрен специальный регистр управляющего сопроцессора CP0 (Регистр 9, Select 0) – Count [1, п. 7.8].
32-битный регистр Count аппаратно инкрементируется на единицу каждый такт процессора. Разница между значениями Count до и после выполнения кода дает точное количество затраченных тактов. Прочитать регистр CP0 из Си-кода можно с помощью встроенного ассемблера (inline assembly):
unsigned int get_cpu_cycles(void) {
    unsigned int cycles;
    // mfc0 - Move From Coprocessor 0
    // $9 - номер регистра Count
    __asm__ __volatile__("mfc0 %0, $9" : "=r"(cycles));
    return cycles;
}
__asm__ – сигнал компилятору, о том, что внутри скобок находится не Си-код, а машинные инструкции. Двойные подчеркивания используются для того, чтобы избежать конфликтов, если в программе вдруг окажется переменная с именем asm.
__volatile__ – строгий запрет на оптимизацию (реорганизацию кода). Для чтения аппаратных регистров это обязательное требование, т. к. значение Count меняется каждый такт само по себе, и компилятор не знает об этом.
"mfc0 %0, $9" – ассемблерная инструкция чтения слова из регистра управляющего сопроцессора CP0 (см. таблицу 1).
mfc0 – команда Move From Coprocessor 0.
%0 – плейсхолдер (заглушка) для «Операнда №0». Компилятор заменит его на имя реального регистра процессора на этапе сборки проекта.
$9 – номер регистра Count сопроцессора CP0.
Двоеточие : отделяет текст ассемблера от секции вывода: описания того, как ассемблерный код возвращает данные обратно в программу на Cи.
списка переменных, с которыми нужно связать результат.
"=r"(cycles) –ограничение (constraint) для компилятора: знак = означает, что переменная доступна только для записи, символ r – указание компилятору выделить для этой операции любой свободный регистр общего назначения, (cycles) – имя переменной в Си-коде, в которую нужно сохранить итоговый результат.
Когда GCC компилирует этот код, он выступает в роли «моста» между кодом на Си и железом:
Компилятор видит, что нужно сохранить результат в переменную cycles. Он выделяет для нее 4 байта в стеке (!), поскольку эта переменная объявлена как локальная с типом unsigned int.
Для выполнения самой инструкции mfc0 ему нужен временный регистр. Компилятор выбирает свободный регистр (в архитектуре MIPS для возврата значений из функций традиционно используется регистр $v0) и подставляет его вместо %0.
Шаблон превращается в реальную машинную инструкцию: mfc0 $v0, $9.
После компиляции кода в файле .dis фрагмент с вызовом данной функции выглядит следующим образом:
80000f88:  40024800   mfc0  v0, c0_count   # Результат inline assembly
80000f8c:  afc20000   sw    v0, 0(s8)      # Сохранение в переменную cycles
80000f90:  8fc20000   lw    v0, 0(s8)      # Загрузка обратно для return
mfc0 v0, c0_count – Компилятор подставил регистр v0 вместо %0, а $9 заменил на псевдоним c0_count. После выполнения этой инструкции аппаратный счетчик тактов прочитан и лежит в регистре v0.
sw v0, 0(s8) – Компилятор сохраняет значение из регистра v0 в оперативную память (в стек) по смещению 0 от указателя кадра s8. Именно здесь физически находится локальная переменная cycles.
lw v0, 0(s8) – В языке Си функция get_cpu_cycles(void) заканчивается на return cycles;. По соглашению о вызовах (ABI) архитектуры MIPS, любая функция должна возвращать свой результат через регистр v0. Поэтому компилятор загружает значение счетчика в v0, чтобы передать вызывающей функции. Очевидно, что компиляция выполнена не оптимально: на текущий момент регистр v0 уже содержит значение счетчика.
Либо, если переменную cycles объявить глобально, то последняя инструкция также была бы лишней.

Влияние оптимизаций компилятора GCC

Компилятор GCC по умолчанию агрессивно оптимизирует код. 
«Пустой» цикл for(int i=0; i<1000; i++) {} будет полностью удален из итогового бинарного файла, так как он не имеет побочных эффектов.
Для корректных замеров необходимо…
· Либо отключить оптимизацию (в начале файла main.c указать директиву препроцессора 
#pragma GCC optimize ("O0")).
· Либо использовать ключевое слово volatile для переменных. Использование volatile сообщает компилятору, что значение переменной может измениться непредсказуемым образом (например, аппаратно или в другом потоке), запрещая кэширование этой переменной в регистрах и ее удаление как "бесполезной".
· Либо внедрять целевые инструкции напрямую через __asm__ __volatile__.
Использование volatile сообщает компилятору, что значение переменной может измениться непредсказуемым образом (например, аппаратно или в другом потоке), запрещая кэширование этой переменной в регистрах и ее удаление как "бесполезной".

В качестве примера преобразования исходного текста на Си в машинный код рассмотрим следующий пример.
start = get_cpu_cycles();
for (i = 0; i < N; i++) {
    c = a + b;
}
end = get_cpu_cycles();
diff = end - start;

После компиляции и дизассемблирования этот код выглядит следующим образом.
# Измерение начального времени (start = get_cpu_cycles();)
80001078: 0c0003b7 	jal	80000edc <get_cpu_cycles> # Вызов функции
8000107c: 00000000 	nop                 # Слот задержки
80001080: afc20010 	sw	v0,16(s8) # Сохраняем результат (v0) по смещению 16 -> 'start'
# Инициализация цикла и переход к условию (i=0;)
80001084: afc0001c 	sw	zero,28(s8)  # Записываем 0 по смещению 28 -> переменная 'i'
80001088: 10000008 	b	800010ac     # Безусловный переход к проверке условия
8000108c: 00000000 	nop                 # Слот задержки
# Тело цикла (c = a + b;)
80001090: 8fc30020 	lw	v1,32(s8)    # Читаем 'a' из памяти в v1
80001094: 8fc20024 	lw	v0,36(s8)    # Читаем 'b' из памяти в v0
80001098: 00621021 	addu	v0,v1,v0     # Сложение без знака: v0 = v1 + v0 (a + b)
8000109c: afc20028 	sw	v0,40(s8)    # Записываем результат в память -> 'c'
# Инкремент счетчика цикла (i++)
800010a0: 8fc2001c 	lw	v0,28(s8)    # Читаем 'i' из памяти
800010a4: 24420001 	addiu	v0,v0,1      # Инкремент: v0 = v0 + 1
800010a8: afc2001c 	sw	v0,28(s8)    # Записываем обновленное 'i' обратно в память
# Проверка условия цикла (i < N)
800010ac: 8fc3001c 	lw	v1,28(s8)    # Читаем 'i' в v1
800010b0: 3c020001 	lui	v0,0x1       # Загружаем старшие 16 бит N: v0 = 0x00010000
800010b4: 344286a0 	ori	v0,v0,0x86a0 # Добавляем младшие 16 бит: v0 = 0x000186A0
800010b8: 0062102b 	sltu	v0,v1,v0     # Беззнаковое сравнение: v0 = (v1 < v0) ? 1 : 0
800010bc: 1440fff4 	bnez	v0,80001090  # Если v0 != 0 (i < N), прыгаем на тело цикла
800010c0: 00000000 	nop                 # Слот задержки
# Измерение конечного результата времени и вычисление разницы
800010c4: 0c0003b7 	jal	80000edc <get_cpu_cycles> # Вызов get_cpu_cycles()
800010c8: 00000000 	nop
800010cc: afc20014 	sw	v0,20(s8)      # Сохраняем 'end' (смещение 20)
800010d0: 8fc30014 	lw	v1,20(s8)      # Загружаем 'end' в v1
800010d4: 8fc20010 	lw	v0,16(s8)      # Загружаем 'start' в v0
800010d8: 00621023 	subu	v0,v1,v0       # Вычитаем: v0 = end - start
800010dc: afc20018 	sw	v0,24(s8)      # Сохраняем 'diff' (смещение 24)


Задание для самостоятельной работы

1. Создать код, реализующий пустой цикл (рекомендованное количество итераций N = 1000 / 10000 / 100000) и измеряющий длительность всего цикла в тактах процессора с помощью регистра Count. Скомпилировать его и открыть файл .dis, убедиться что компилятор не удалил цикл в процессе оптимизации. Выделить в дизассемблированном листинге блок инструкций, соответствующий одной итерации цикла (включая условие выхода и слот задержки). Выполнить теоретический расчет времени выполнения одной итерации. Для этого необходимо:
· Для каждой ассемблерной инструкции из тела цикла найти ее характеристики в таблицах раздела 4 руководства [1] (например, Таблица 4.1 для арифметики, Таблица 4.2 для ветвлений, Таблица 4.4 для NOP). Обратить внимание на столбцы «Поток» (F, M или FP), «Задержка» и «Повтор».
· Учесть суперскалярность ядра: определить, какие инструкции могут выполняться параллельно за один такт, так как относятся к разным функциональным потокам (согласно Таблице 2.1 и разделу 2 [1]).
· Учесть наличие слота задержки команды ветвления (раздел 1.2 [1])
Сравнить полученное теоретическое значение (в тактах) с результатом аппаратного замера. Сделать вывод о наличии или отсутствии скрытых простоев конвейера (stalls) при выполнении данного фрагмента кода.

2. Внутрь цикла добавить исследуемую арифметическую операцию (например, на выбор из таблицы 1). Провести анализ файла .dis как в п.1. Определить насколько изменилось количество затраченных на цикл тактов и из-за чего это произошло.

3. Попробовать поместить в 1 цикл две независимые инструкции, например, одну арифметическую (F-поток) и одну загрузку из памяти или перемещение (M-поток). Сравнить время с вариантом, где используются 2 арифметические операции. Проанализировать результат.

Разработчики платы БАГЕТ-ПЛК1-01 [2] рекомендуют использовать среду разработки и структуру проекта, описанные в [3] и [4, раздел 3]. 
Задания к лабораторной работе подразумевают, что работа выполняется в ОС Windows с предустановленной виртуальной машиной WSL2 с Debian [3] и ППП МК [4-5]. Проекты на языке Cи следует создавать в папке ./psp_mc/apps/ .
Для формирования импульса можно использовать функцию delay_us(), для замера времени работы –__micros(), для вывода результата – __print_console(), для форматирования строки вывода – itoa() и intToHex().

